[网络连接] [已解决]怎样通过批处理更改电脑ip地址，并打开网页

Model2015

麻烦各位帮忙看下能否实现这样的功能呢？支持win7 XP环境，界面显示两个选项：1.设置光猫 2.测试网速 需要达到的功能是，选择一的时候自动修改电脑ip为固定ip192.168.18.18 子网掩码255.255.255.0 网关192.168.18.1 然后调用ie自动打开192.168.18.3这个地址。选择2的时候把电脑ip地址自动改成自动获取，然后打开adsl.online.com.cn

34205

笔记本小问题因为你的有些电脑创建过多次操作的本地连接，则有可能变成“本地连接2”，则 “本地连接” 这个标题对不上，经常有的是“无线连接”也容易干扰....

Model2015

回复 10# pcl_test


    我说怎么今天一测试好了呢，这个写的太好了，方便太多太多了！谢谢了

Model2015

回复 10# pcl_test


    谢谢版主，经测试很完美，谢谢了

pcl_test

回复 9# Model2015

测试了下，win7系统的笔记本设为自动获取的，需网卡已连在网络上

Model2015

回复 8# pcl_test


  我用台式机测试成功，但是笔记本一直不成功，笔记本选择2的话依然是手动分配选项，只不过IP地址里被清空了，禁用无线网卡，重装系统都不行！希望版主再给我研究下，我们的使用环境都是笔记本，明天我用笔记本XP系统继续测试下

pcl_test

回复 7# Model2015
修改开头的一小段

@echo off & setlocal enabledelayedexpansion
:0
cls
ver|find "5.2" >nul&&(
    echo q|debug>nul
    >nul (chcp 437&graftabl 936)
    echo 请选择：1.设置光猫   2.测试网速
    (echo e100 CD 16 B4 4C CD 21&echo g&echo q)|debug>nul
    set err=!errorlevel!
    >nul (chcp 437&graftabl 936)
    if !err!==49 goto :设置光猫
    if !err!==50 goto :测试网速
)||(
    choice /c 12 /n /m "请选择：1.设置光猫   2.测试网速"
    if !errorlevel!==1 goto :设置光猫
    if !errorlevel!==2 goto :测试网速
)
ping -n 2 0 >nul&goto :0
复制代码

Model2015

回复 6# pcl_test


    这个能做成输入序号不按回车自动运行么？

pcl_test

回复 5# Model2015

参数错误没关系，不影响效果，已做屏蔽错误提示修改

Model2015

回复 4# pcl_test


    这次功能没问题了，就是一选择二就会出现参数错误，但是功能是正常的，不知道为什么！劳烦版主再看一下

pcl_test

回复 3# Model2015


    已修改

Model2015

谢谢版主，这个自动分配IP地址功能是不是笔记本的不能用呢？我测试了下，台式机功能全部正常，但是笔记本选择自动分配不能成功，不行的话我就把无线网卡禁用了。还有一个问题就是可不可以设置成选完1操作完之后可以继续选择2继续操作，而不是“请按任意键继续呢？”，我需要操作完1之后，然后紧接着就需要再这个界面选择2操作。然后这个界面等我需要关闭的时候手动关闭。麻烦版主能帮忙再修改下呢？

pcl_test

@echo off
:0
cls
echo;1.设置光猫   2.测试网速
echo;
set c=
set /p c=输入序号并按回车键：
if "%c%" equ "1" (goto :设置光猫) else if "%c%" equ "2" (goto :测试网速) else goto :0

:设置光猫
set ip=192.168.18.18
set mask=255.255.255.0
set gateway=192.168.18.1
ver|find "5.2" >nul&&(
    netsh interface ip set address name="本地连接" source=static addr=%ip% mask=%mask% gateway=%gateway%
)||(
    netsh interface ipv4 set address name="本地连接" source=static address=%ip% mask=%mask% gateway=%gateway%
)
echo;设置静态IP完成
ping -n 5 0 >nul&start "" "http://192.168.18.3"
goto :0

:测试网速
ver|find "5.2" >nul&&(
    netsh interface ip set address name="本地连接" source=static addr=0.0.0.0 mask=0.0.0.0 gateway=0.0.0.0 >nul
    netsh interface ip set address name="本地连接" source=dhcp
    netsh interface ip set dns name="本地连接" source=dhcp
)||(
    netsh interface ipv4 set address name="本地连接" source=static address=0.0.0.0 mask=0.0.0.0 gateway=0.0.0.0 >nul
    netsh interface ipv4 set address name="本地连接" source=dhcp
    netsh interface ipv4 set dnsservers name="本地连接" source=dhcp
)
echo;设置动态IP完成
ping -n 5 0 >nul&start "" "http://adsl.online.com.cn"
goto :0
复制代码