[数值计算] [已解决]批处理如何将连续的数字按指定格式进行合并，不连续的数字保持原样？

chouxia

变量现在的值为s=101,102,339,340,341,342,343,592,593,594,595
现在想把值换改成如下形式s=101-102,339-343,592-595
代码中应该如何实现？
我一点思路都没有

chouxia

回复 9# 回家路上


    大哥，这段代码我是真不懂，能解释下吗？

回家路上

没看出前面的1a有什么特殊意义

C:>set b=1a

C:>set /a "2-b-1"
0
复制代码

删了吧

for %%i in (%s% a) do (
... ...
echo;!str:~1,-3!
复制代码

回家路上

只是赶巧了，如果你的s不是2开头，而是：

set s=3,4,5,6,7,8,9,10,11,12,13,14,15,16,17,18,19,20
复制代码

就能正确显示，原因？你猜O(∩_∩)O！

chouxia

回复 6# WHY

当s等于如下值的时候str没有输出值（这个s的值有可能是任意数字）
set s=2,3,4,5,6,7,8,9,10,11,12,13,14,15,16,17,18,19,20
这代码没看懂，哪位能帮忙改一下？
哪位又可以帮忙指教一下？
拜谢拜谢！

WHY

@echo off & setlocal enabledelayedexpansion
set s=101,102,339,340,341,342,343,592,593,594,595
for %%i in (1a %s% a) do (
    set /a "1/(%%i-a-1)" && set "str=!str!!a!,%%i-"
    set "a=%%i"
)2>nul
echo;!str:~3,-3!
pause
复制代码

回家路上

@echo off & setlocal enabledelayedexpansion
set s=101,102,339,340,341,342,343,592,593,594,595
for %%i in (%s%) do (
	if not defined end (
		set begin=%%i& set end=%%i
	) else (
		set /a flag=%%i-end-1
		if not !flag!==0 (
			set t=!t!,!begin!-!end!
			set begin=%%i& set end=%%i
		)else set end=%%i
	)
)
set t=%t%,%begin%-%end%
set s=%t:~1%

echo;%s%
pause
复制代码

再改一下O(∩_∩)O！

@echo off & setlocal enabledelayedexpansion
set s=101,102,339,340,341,342,343,592,593,594,595
for %%i in (%s%,shenmegui) do (
	if not defined end (
		set s=& set begin=%%i& set end=%%i
	) else (
		set /a flag=%%i-end-1
		if not !flag!==0 (
			if defined s (
				set s=!s!,!begin!-!end!
			)else set s=!begin!-!end!
			set begin=%%i& set end=%%i
		)else set end=%%i
	)
)
echo;%s%
pause & exit /b
复制代码

chouxia

回复 3# 回家路上


    说白了变量s被逗号隔开的数字。相邻的几个数字为连续值的时候取第一个数字和最后一个数字，中间用减号隔开，
举例中输出结果应该是101-102,339-343,592-595
101,102,连续数字，所以改为101-102
339,340,341,342,343,连续数字，改为339-343
592,593,594,595 连续数字，改为592-595
所以
s的值最终为：101-102,339-343,592-595

回家路上

然而并不知道你每两个数字的对应关系是什么

@echo off & setlocal enabledelayedexpansion
set s=101,102,339,340,341,342,343,592,593,594,595
for %%i in (%s%) do (
	set /a n+=1,m=n%%2
	if !m!==0 (set sp=-)else set sp=,
	set re=!re!!sp!%%i
)
set s=%re:~1%
echo;%s%
pause
复制代码

尘丶

好了 你再自己修改下就可以了

@echo off & setlocal enabledelayedexpansion
set s=101,102,339,340,341,342,343,592,593,594,595
set n=1
for %%a in (%s%) do (
	if !n!==1 (
	   set k=%%a&set /a n+=1
	) else (
	     if %%a==!j! (
	        set k=!k!-%%a
	     ) else (
	        set k=!k!,%%a
	     )
	)
	set /a j=%%a+1
)
for %%a in (!k!) do (
set l=%%a
set /p=!l:~,4!!l:~-3!,<nul
)
pause
复制代码