[系统相关] 请教BeePhoto.exe（在屏幕上显示图片）怎么用？

locoman

BeePhoto.exe（在屏幕上显示图片）怎么用？

论坛中有这个命令行工具，但没有使用说明，该工具也没有命令行帮助信息，想用又不知道怎么用！
请问大神们知道这个工具的详细用法吗？谢谢指点！！

0475

回复 12# Batcher


    感谢大神，太完美了，谢谢

Batcher

回复 10# 0475

@echo off
set "PictureName1=img\209.png"
set "PictureName2=img\201.jpg"
set "PictureName3=img\202.jpg"
cd /d "%~dp0"
for /f "tokens=1-2" %%a in ('mshta VBScript:Execute("CreateObject(""Scripting.Filesystemobject"").GetStandardStream(1).Write(screen.width&"" ""&screen.height)"^)(close^)') do (
    set "ScreenWidth=%%a"
    set "ScreenHeight=%%b"
)
for %%i in (%PictureName1% %PictureName2% %PictureName3% ) do (
    call :GetPicSize "%%i"
)
goto :eof

:GetPicSize
for /f "tokens=1,3" %%a in ('nconvert -info "%~1"') do (
    set "str=%%a"
    if "%%a" equ "Width" (
        set "PictureWidth=%%b"
    ) else if "%%a" equ "Height" (
        set "PictureHeight=%%b"
    )
)
set /a PositionX=(ScreenWidth-PictureWidth)/2
set /a PositionY=(ScreenHeight-PictureHeight)/2
BeePhoto /p:"%~1" /x:%PositionX% /y:%PositionY%
复制代码

0475

想要连续显示多个图片，每个图片像素不一样，判断图片居中显示

0475

批处理调用 BeePhoto 在屏幕上居中显示一个图片（调用 nconvert 获取图片的宽度和高度）
Batcher 发表于 2020-10-20 23:47

    大佬，连续显示多个图片如何弄？我只会这样，代码太多了
@echo off
set "ictureName=img\209.png"
set "PictureName2=img\201.jpg"
set "PictureName3=img\202.jpg"
cd /d "%~dp0"
for /f "tokens=1,3" %%a in ('nconvert_6.8 -info "%PictureName%"') do (
    set "str=%%a"
    if "%%a" equ "Width" (
        set "PictureWidth=%%b"
    ) else if "%%a" equ "Height" (
        set "PictureHeight=%%b"
    )
)
for /f "tokens=1-2" %%a in ('mshta VBScript:Execute("CreateObject(""Scripting.Filesystemobject"").GetStandardStream(1).Write(screen.width&"" ""&screen.height)"^)(close^)') do (
    set "ScreenWidth=%%a"
    set "ScreenHeight=%%b"
)
set /a PositionX=(ScreenWidth-PictureWidth)/2
set /a PositionY=(ScreenHeight-PictureHeight)/2
BeePhoto /p:"%PictureName%" /x:%PositionX% /y:%PositionY% /t:6000

for /f "tokens=1,3" %%a in ('nconvert_6.8 -info "%PictureName2%"') do (
    set "str=%%a"
    if "%%a" equ "Width" (
        set "PictureWidth=%%b"
    ) else if "%%a" equ "Height" (
        set "PictureHeight=%%b"
    )
)
for /f "tokens=1-2" %%a in ('mshta VBScript:Execute("CreateObject(""Scripting.Filesystemobject"").GetStandardStream(1).Write(screen.width&"" ""&screen.height)"^)(close^)') do (
    set "ScreenWidth=%%a"
    set "ScreenHeight=%%b"
)
set /a PositionX=(ScreenWidth-PictureWidth)/2
set /a PositionY=(ScreenHeight-PictureHeight)/2
BeePhoto /p:"%PictureName2%" /x:%PositionX% /y:%PositionY% /t:6000

for /f "tokens=1,3" %%a in ('nconvert_6.8 -info "%PictureName3%"') do (
    set "str=%%a"
    if "%%a" equ "Width" (
        set "PictureWidth=%%b"
    ) else if "%%a" equ "Height" (
        set "PictureHeight=%%b"
    )
)
for /f "tokens=1-2" %%a in ('mshta VBScript:Execute("CreateObject(""Scripting.Filesystemobject"").GetStandardStream(1).Write(screen.width&"" ""&screen.height)"^)(close^)') do (
    set "ScreenWidth=%%a"
    set "ScreenHeight=%%b"
)
set /a PositionX=(ScreenWidth-PictureWidth)/2
set /a PositionY=(ScreenHeight-PictureHeight)/2
BeePhoto /p:"%PictureName3%" /x:%PositionX% /y:%PositionY% /t:6000

Batcher

批处理调用 BeePhoto 在屏幕上居中显示一个图片（调用 nconvert 获取图片的宽度和高度）

@echo off
set "PictureName=屏幕水印001.bmp"
cd /d "%~dp0"
for /f "tokens=1,3" %%a in ('nconvert -info "%PictureName%"') do (
    set "str=%%a"
    if "%%a" equ "Width" (
        set "PictureWidth=%%b"
    ) else if "%%a" equ "Height" (
        set "PictureHeight=%%b"
    )
)
for /f "tokens=1-2" %%a in ('mshta VBScript:Execute("CreateObject(""Scripting.Filesystemobject"").GetStandardStream(1).Write(screen.width&"" ""&screen.height)"^)(close^)') do (
    set "ScreenWidth=%%a"
    set "ScreenHeight=%%b"
)
set /a PositionX=(ScreenWidth-PictureWidth)/2
set /a PositionY=(ScreenHeight-PictureHeight)/2
BeePhoto /p:"%PictureName%" /x:%PositionX% /y:%PositionY%
复制代码

Batcher

批处理调用 BeePhoto 在屏幕上居中显示一个图片（手工设置图片宽度和高度）

@echo off
set "PictureName=屏幕水印001.bmp"
set "PictureWidth=800"
set "PictureHeight=700"
cd /d "%~dp0"
for /f "tokens=1-2" %%a in ('mshta VBScript:Execute("CreateObject(""Scripting.Filesystemobject"").GetStandardStream(1).Write(screen.width&"" ""&screen.height)"^)(close^)') do (
    set "ScreenWidth=%%a"
    set "ScreenHeight=%%b"
)
set /a PositionX=(ScreenWidth-PictureWidth)/2
set /a PositionY=(ScreenHeight-PictureHeight)/2
BeePhoto /p:"%PictureName%" /x:%PositionX% /y:%PositionY%
复制代码

locoman

回复 6# Batcher


    非常感谢您！
您一直都是那样的热忱和无私，是网络江湖之楷模！我已在微信群中发了红包以资答谢！

Batcher

回复 1# locoman


BeePhoto 用法：
http://bbs.bathome.net/thread-7755-1-1.html#pid51205

Batcher

回复 4# locoman


    我找不到使用说明和详细用法

locoman

回复 3# Batcher


   论坛中就有，请看：
http://bbs.bathome.net/viewthread.php?tid=3934

http://www.bathome.net/thread-3981-1-1.html

谢谢您一直的帮助和指导！

Batcher

回复 2# locoman


    我没有用过这个工具

locoman

@Batcher大神，您知道怎么用吗？