[文件操作] 批处理自动复制文件夹下的前一天的所有文件

79794133

有文件夹A，文件夹B， 要把文件夹A中的创建时间为前一天的文件复制到文件夹B中，比如今天是9月4号，把9月3号创建的文件复制过去，到9月5号把9月4号的文件复制过去。请各位前辈大佬指点一下

hztccy

回复 16# 79794133


    这个我知道呀，所以我才说在不考虑其他时间的情况下，这个也是可以呀。

79794133

回复 14# hztccy


    robocopy "C:\123" "C:\234" /maxage:1
这个复制时差1天内的文件，不能完美的只复制昨天的文件

79794133

回复 12# Batcher


@echo off
set "SrcFolder=E:\A"
set "DaysAgo=1"
for /f %%i in ('powershell -c "Get-Date (Get-Date).AddDays(-%DaysAgo%) -uformat "%%Y/%%m/%%d""') do (
    set "DstDate=%%i"
)
set "yesterday=%DstDate:~0,4%%DstDate:~5,2%%DstDate:~8,2%
md  e:\backup\%yesterday%
set   "DstFolder=e:\backup\%yesterday%"

for /f "delims=" %%i in ('dir /b /a-d "%SrcFolder%"') do (
    call :CheckFile "%%i"
)
goto :eof
:CheckFile
for /f "skip=5" %%j in ('dir /tc "%SrcFolder%\%~1"') do (
    if "%%j" equ "%DstDate%" (
        copy /y "%SrcFolder%\%~1" "%DstFolder%\"
    )
    goto :eof
)

这是通过你的方法改良后的代码，完美解决了我的所有问题，你是我偶像爱你哦

hztccy

在不考虑其他时间的情况下
其实
robocopy也是可以的

robocopy "C:\123" "C:\234" /maxage:1

79794133

回复 12# Batcher


    大佬V5，小弟膜拜

Batcher

回复 3# 79794133

@echo off
set "SrcFolder=D:\Test\A"
set "DstFolder=D:\Test\B"
set "DaysAgo=1"
for /f %%i in ('powershell -c "Get-Date (Get-Date).AddDays(-%DaysAgo%) -uformat "%%Y/%%m/%%d""') do (
    set "DstDate=%%i"
)
for /f "delims=" %%i in ('dir /b /a-d "%SrcFolder%"') do (
    call :CheckFile "%%i"
)
goto :eof

:CheckFile
for /f "skip=5" %%j in ('dir /tc "%SrcFolder%\%~1"') do (
    if "%%j" equ "%DstDate%" (
        copy /y "%SrcFolder%\%~1" "%DstFolder%\"
    )
    goto :eof
)
复制代码

hlzj88

感谢newswan提醒，细节决定成败。
回复 8# 79794133

把/on 改/tc。

newswan

创建时间 ？ 修改时间
dir 一般 得到的时间是修改时间
dir /tc 才是创建时间

2楼已经写明了

hlzj88

@echo off&&setlocal enabledelayedexpansion
for /f %%a in ('cscript //nologo yester.vbs') do set yesterday=%%a
for /f %%i in ('dir /b /s /on "a\*.txt"') do (
  echo %%:~ni
  set mm=%%~ti
  set sj=!mm:~0,4!!mm:~5,2!!mm:~8,2!
  if !sj! == %yesterday% move /y %%i b\
)
pause
复制代码

需和你的vbs放一起

79794133

回复 7# hlzj88


   d = date() - 1
wscript.echo year(d) * 10000 + month(d) * 100 + day(d)
以上是VBS代码，新建记事本保存为.VBS即可。

for /f %%a in ('cscript //nologo yester.vbs') do set yesterday=%%a
这一句保存为.bat文件，yesterday即是昨天的日期

然后用批处理获得文件夹下的文件创建日期，与yesterday进行对比，这样你看行吗？

hlzj88

回复 6# 79794133
按你顶楼的说法，只有两个文件夹，a里只保留当天的文件，不是当天的文件都是到b，无非是哪一天执行批处理，这样子前天大前天有关系吗。也许你该改顶楼的要求细节。

如果是不定时执行，又只要昨天的文件，我没有能力判断昨天的日期，比如跨月的日子。今天1号，昨天是30号，31号，不能搞定。

79794133

回复 5# hlzj88


    那还有前天的，大前天的，大大前天的文件呢，我只想要昨天的文件

hlzj88

假设是每天都运行的情况，即把不等于今天的文件复制到b文件夹。因为不可能有明天的文件。

@echo off&&setlocal enabledelayedexpansion
for /f %%i in ('dir /b /s /on "a\*.*"') do (
  set mm=%%~ti
  set sj=!mm:~0,10!
  if !sj! == %date:~0,10% (echo 今天的%%i) else (move /y %%i b\)
  )
pause
复制代码

79794133

回复 2# Batcher


    文件名是不包含日期的，我的想法是通过每个文件的创建日期与前一天的日期进行比较，如果相同就进行复制操作。
比如：文件4.txt的创建日期为2021/09/04  13:04，我们只截取前面的日期2021/09/04或者20210904，今天是9月5号，昨天就是9月4号，然后把截取的日期与昨天的日期进行比较，如果两个日期相同就进行复制操作