[文件操作] 求助批处理把文件名最大的加1

单车少男

2024年01月19日 - 收集池清单v5.XLS
2024年01月19日 - 清单v5.XLS
2024年01月19日 - 收集池清单v4.XLS
2024年01月19日 - 清单v4.XLS
2024年01月19日 - 收集池清单v3.XLS
2024年01月19日 - 清单v3.XLS


运行批处理，V5（最大的数）自动加1，成V6

怎么处理？

单车少男

回复 21# 77七


    非常感谢

77七

回复 20# 单车少男


   因为我水平十分有限，有问题站里发帖就行，遇到我不会的我也能学习下。

单车少男

回复 19# 77七


    这个可以，加个好友呢

77七

回复 18# 单车少男


   代码第4行改为

for /f "delims=" %%i in ('dir /b /a-d "*v*.*" ^|findstr /rviec:"\.pdf"') do (
复制代码

单车少男

回复 17# 77七


    可以了，能加个好友吗？

另外文件格式能不能排除一下PDF文件，

77七

@echo off
cd /d "%~dp0"
setlocal enabledelayedexpansion
for /f "delims=" %%i in ('dir /b /a-d "*v*.*"') do (
	set file=%%i
	for /f "delims=" %%a in ("!file:v=/!") do (
		set /a n=%%~na+1,m=1000000+%%~na
		set #"!file:v%%~nxa=!"#"!m!"#"!file!"=!file:%%~nxa=!!n!%%~xi
	)
)
for /f "tokens=1-4 delims=#=" %%a in ('set # ^|sort /r') do (
	if not defined _"%%~a" (
		set _"%%~a"=1
		copy "%%~c" "%%d"
		start "" "%%d"
		timeout 2
	)
)
endlocal
pause
复制代码

回复 16# 单车少男

单车少男

回复 15# 77七


    新文件，文件大小为0，

77七

回复 9# 单车少男


  

@echo off
cd /d "%~dp0"
setlocal enabledelayedexpansion
for /f "delims=" %%i in ('dir /b /a-d "*v*.*"') do (
	set file=%%i
	for /f "delims=" %%a in ("!file:v=/!") do (
		set /a n=%%~na+1,m=1000000+%%~na
		set #"!file:v%%~nxa=!"#"!m!"=!file:%%~nxa=!!n!%%~xi
	)
)
for /f "tokens=1-3 delims=#=" %%a in ('set # ^|sort /r') do (
	if not defined _"%%~a" (
		set _"%%~a"=1
		cd.>"%%c"
		start "" "%%c"
		timeout 2
	)
)
endlocal
pause
复制代码

77七

回复 13# 单车少男


   
文件类型没有关联软件吗？
start "" "软件完整路径" "文件名" 试试

单车少男

回复 12# 77七


    出错的

77七

回复 11# 单车少男


   start "" "%%d"

单车少男

回复 7# 77七


   

"%%d"

改成  start   "%%d"  怎么不能打开么

77七

回复 9# 单车少男


   所以说我在2楼让你多发几个文件名..代码应该重写了...

单车少男

回复 8# 77七


    物联截污V3.docx
    物联截污V4.docx