[注册表类] 批处理如何从注册表中读取鼠标右键信息？

jay_16

如何从注册表中读取鼠标右键信息，包括新建的文件名称？在网上查晕了，还是没弄懂。。

hanyeguxing

如果要查找“新建”的文件类型，则递归HKLM\SOFTWARE\Classes\中所有包含ShellNew子项的项

jay_16

2# hanyeguxing


能帮忙写一下代码吗？我现在正处于学习注册表阶段，麻烦你了。谢谢

CrLf

reg query hkcr /f shellnew /s

hanyeguxing

xp sp3 下以递归 HKLM\SOFTWARE\Classes\ 中所有包含 ShellNew 子项的项为例：

@echo off&setlocal enabledelayedexpansion
set "n=reg query HKLM\SOFTWARE\Classes"
for /f "skip=4 tokens=2 delims=R>" %%a in ('%n%\.bat /ve') do set "m=%%a"
for /f "skip=6 delims=" %%a in ('%n%') do (
	set "a=%%a"
	if not "!a:~36,1!"=="." goto:e
	%n%\!a:~36!\ShellNew >nul 2>nul&&for /f "skip=4 tokens=3 delims=%m%" %%b in ('%n%\!a:~36! /ve') do for /f "skip=4 tokens=3 delims=%m%" %%c in ('%n%\%%b /ve 2^>nul') do echo;!a:~36! %%c
)
:e
echo;完成&pause
复制代码

jay_16

5# hanyeguxing


非常感谢。问一些问题，你不用具体解释，笼统的说一下就可以。又麻烦你了。

for /f "skip=4 tokens=2 delims=R>" %%a in ('%n%\.bat /ve') do set "m=%%a"
复制代码

'%n%\.bat是每个项下都有.bat子项吗？ 跳过前4行，提取以R>为分隔符的第2段，取到的是什么值？我在这行下面用echo %m%&pause试了一下，显示的是ECHO处于关闭状态！？
后面那三个for do让我彻底晕了。

hanyeguxing

6# jay_16


@echo off&setlocal enabledelayedexpansion
set "n=reg query HKLM\SOFTWARE\Classes"
for /f "skip=4 tokens=2 delims=R>" %%a in ('%n%\.bat /ve') do set "m=%%a"
提取tab制表符，因为论坛无法复制这个
for /f "skip=6 delims=" %%a in ('%n%') do (
递归HKLM\SOFTWARE\Classes下所有项名（不包括子项），skip=6使得第一项名就带.
        set "a=%%a"
        if not "!a:~36,1!"=="." goto:e
只递归项名为扩展名的，即项名第一个字符（完整项名第35个字符）为.
        %n%\!a:~36!\ShellNew >nul 2>nul&&for /f "skip=4 tokens=3 delims=%m%" %%b in ('%n%\!a:~36! /ve') do for /f "skip=4 tokens=3 delims=%m%" %%c in ('%n%\%%b /ve 2^>nul') do echo;!a:~36! %%c
检查这些项中是否有ShellNew子项，有则执行后面两个for。第一个for解析获取该扩展名对应的项名（文件类型的项名），第二个for获取该项名对应的文件类型名。这样就有了扩展名!a:~36!对应的文件类型%%c
)
:e
echo;完成&pause
运行结果示例：

.bat MS-DOS 批处理文件
.cmd Windows NT 命令脚本
.doc Microsoft Word 文档
.lnk 快捷方式
.txt 文本文档
完成
请按任意键继续. . .

slore

遍历太慢了。。。有个项是管理新建项的。

HKCU\Software\Microsoft\Windows\CurrentVersion\Explorer\Discardable\PostSetup\ShellNew

hanyeguxing

8# slore


从 HKCU\Software\Microsoft\Windows\CurrentVersion\Explorer\Discardable\PostSetup\ShellNew 查询是个简便的方法（在没有意外的情况下，因为这个键可能和别的键值对应不上）

cjiabing

我的做法：
直接用“Registry Workshop”搜索包含指定关键词的内容，比如“shellnew”，一搜一大堆，然后逐个去排除，基本上能解决。
比如
结合昨晚阅读的一个作品，发给你参考：

@echo off 
::清理uusee网页右键
reg delete "HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Internet Explorer\Extensions\{998A88A0-A355-809B-831C-B83A80000991}"   /f 
reg delete "HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Internet Explorer\Extensions\{998A88A0-A355-809B-831C-B83A80000991}"   /f 
reg delete "HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Internet Explorer\Extensions\{998A88A0-A355-809B-831C-B83A80000991}"   /f 
::清除pps自启动
reg add  HKEY_CURRENT_USER\Software\Microsoft\Windows\CurrentVersion\Run /t REG_EXPAND_SZ /v "PPS Accelerator"  /f  
::清理vagaa网页右键
reg delete "HKEY_CURRENT_USER\Software\Microsoft\Internet Explorer\MenuExt\&V使用Vagaa哇嘎下载"  /v   使用Vagaa哇嘎下载  /f
reg delete "HKEY_CLASSES_ROOT\Directory\shell\添加到Vagaa共享"  /v  添加到Vagaa共享  /f
::清理bat和txt右键的print打印选项
reg delete HKEY_CLASSES_ROOT\batfile\shell\print\  /f
reg delete HKEY_CLASSES_ROOT\txtfile\shell\print\  /f
::在右键添加“新建BAT文件”
reg add HKCR\.bat\ShellNew /v nullfile /f >nul 
reg add HKCR\batfile /ve /d bat@.bat /f >nul
复制代码

注意“bat@”就是你新建的bat文件名，不懂怎么弄路径，直接将“@echo off”写到这个新建bat中去。
直接在bat文件上可以新建右键，比较简单：
reg add HKEY_CLASSES_ROOT\batfile\shell\啦啦啦\command /t REG_SZ /ve  /d  C:\啦啦啦.bat   /f

CrLf

@reg query hkcr /k /f shellnew /s|@findstr /x "[^\\]\\\.[^\\]*\\ShellNew"
复制代码