[其他] 批处理命令if里面第二个变量没有获取到值？

goodwzb

求助大牛，如下代码片断，为何我的第二个变量v2没有获取到值？谢谢！
脚本如下：

@echo off

echo pls input v1 value......
set /p V1=input:

if "%v1%" == "var1" (
  echo yes,v1 value is: %v1%
  echo pls input v2 value......
  set /p v2=input:
  echo you input v2 value is: %v2%
)

pause
复制代码

运行过程及输出如下：

pls input v1 value......
input:var1
yes,v1 value is: var1
pls input v2 value......
input:var2
you input v2 value is:  REM注释： 显然这里v2变量并未接收到值
Press any key to continue . . .

Batcher

@echo off
setlocal enabledelayedexpansion
echo pls input v1 value......
set /p v1=input:
if "%v1%" == "var1" (
    echo yes,v1 value is: %v1%
    echo pls input v2 value......
    set /p v2=input:
    echo you input v2 value is: !v2!
)
pause
复制代码

goodwzb

回复 2# Batcher


   验证通过，非常感谢管理员，谢谢，谢谢。

R458-08

@echo off

setlocal enabledelayedexpansion

echo pls input v1 value......

set /p V1=input:


if "%v1%" == "var1" (

     echo yes,v1 value is: %v1%

     echo pls input v2 value......
     set /p v2=input:
  
     echo you input v2 value is: !v2!

)


pause

R458-08

运行结果不是一样哪里错了呢，照抄的呀

goodwzb

运行结果不是一样哪里错了呢，照抄的呀
R458-08 发表于 2014-5-12 10:46

    我自己是能验证通过的，第v2变量是有接收到值的，不知你的问题在哪里？把输出结果帖一下呢！
下面是我改用管理员修改版后的输出结果：
pls input v1 value......
input:var1
yes,v1 value is: var1
pls input v2 value......
input:var2
you input v2 value is: var2  这里已经成功获取到值了
Press any key to continue . . .

R458-08

pls input v1 value......
input:        （输入一个值）
请按任意键继续...   (按任意键结束）

goodwzb

pls input v1 value......
input:        （输入一个值）
请按任意键继续...   (按任意键结束）
R458-08 发表于 2014-5-12 15:01

    input:后面是需要你实际敲键盘来输入一个字符串的，你看我上面就输入了一个var1字符串，而你的冒号后面却显示空白，说明你什么也没有输入，脚本自然直接跑到最后一行了