[文件操作] 批处理命令for /f 集里的("abcdefg")，如何分成7段？

smatenchen

for /f 集里的("abcdefg")，如何分成a,b,c,d,e,f,g，这样的7段？


1
for /f “delims=?”%%i in ("abcdefg") do echo %%i
如何将"abcdefg"分成7段，再显示成“a b c d e f g”，或"a-b-c-d-e-f-g"，或"a,b,c,d,e,f,g"呢？


2
用什么分隔符呢？命令语句怎么写呢？

qixiaobin0715

字符连在一起，你说哪里有分隔符呢？应用你所说的for /f加delims无法分隔，可以考虑其它方式：

@echo off
set var1=abcdefg
:a
set var2=%var1:~0,1%
set var1=%var1:~1%
echo,%var2%
if not "%var1%"=="" goto :a
pause
复制代码

smatenchen

回复 2# qixiaobin0715



1
感谢大神！


2
你的代码，有效。


3
鄙人的意思是，要显示成“a b c d e f g”，或"a-b-c-d-e-f-g"，或"a,b,c,d,e,f,g"，
而非单显。


4
大神，有解法吗？

qixiaobin0715

回复 3# smatenchen

@echo off
set var1=abcdefg
:a
set var2=%var1:~0,1%
set var1=%var1:~1%
set var=%var%,%var2%
if not "%var1%"=="" goto :a
set var=%var:~1%
echo,%var%
pause
复制代码

smatenchen

回复 4# qixiaobin0715



1
感谢大神！


2
大神的代码，有效。感谢！


3
这样传递变量，蛮有趣的。


4
代码的世界，人类的思维不好懂。


5
二进制思维，如何跃升为人类思维，自然语言？


6
人类的思维，是如何运作的？怎么完成逻辑运算？

idwma

回复 5# smatenchen


    5给道友推荐一本书 '龙书'

smatenchen

回复 6# idwma


   

hfxiang

@echo off
setlocal EnableDelayedExpansion
set "var1=abcdefg"
set "var2="
for /l %%i in (0,1,6) do call set "var2=!var2!-%%var1:~%%i,1%%"
echo;%var2:~1%
endlocal

smatenchen

回复 8# hfxiang



@echo off
setlocal EnableDelayedExpansion
set "var1=abcdefg"
set "var2="
for /l %%i in (0,1,6) do call set "var2=!var2!-%%var1:~%%i,1%%"
echo;%var2:~1%
endlocal

1，
感谢大神！

2，
其中，do call set，是什么用法？

3，
call不是用来调用其它批处理的吗？
怎么还可以有这样的用法吗？
具体含义，请大神细解一下。

4，
省掉call，写成do set，不行吗？

5，
%var1:~%%i,1%，这句含义明确，再在其外套一层%%，是何意呢？

6，
因为，其内有%%i，故也要仿照使用%吗？。

hfxiang

第2、第3及第5其实是同1个问题：do call set 主要为解决for内字符串截取时“~”后跟变量的问题；

第4个问题：省掉 call，写成 do set，行不行你可自行测试（代码已是现成，其实测试才是最好的老师）；

第6个问题：你说对了。

smatenchen

回复 10# hfxiang



1，
感谢大神！


2，
查看call的帮助，没有这类用法的讲解。


3，
for的帮助，也没细讲，如何用转义，用变量……。


4，
这样，学起来就费劲了！
得从其它地方去一点点积累了。


5，
微软，甚不是个玩艺哎！

ZDG0000

沙雕年年有！！！

smatenchen

回复 12# ZDG0000

CrLf

@echo off & setlocal enabledelayedexpansion
cmd /u /c "echo abcdefg" | for /f "delims=" %%a in ('more') do (
 for %%b in (%%a) do echo %%b
)
复制代码

hfxiang

回复 14# CrLf


太厉害了！！！但不知其所以然。
同时俺在Win10命令行下，如下单条指令也能出同样的结果，太神奇了
cmd /u /c "echo abcdefg"|for /f "delims=" %a in ('more') do @echo %a