Batcher

@echo off
set ftpUser=xxx
set ftpPass=XXX
set ftpIP=xxx
set ftpFolder=/path/
set DownFolder=F:\path\
>"%tmp%\MyDel.vbs" echo dt=date()-1
>>"%tmp%\MyDel.vbs" echo s=right(year(dt),4) ^& right("0" ^& month(dt),2) ^& right("0" ^& day(dt),2)
>>"%tmp%\MyDel.vbs" echo wscript.echo s
for /f %%a in ('cscript /nologo "%tmp%\MyDel.vbs"') do set yesterday=%%a
set ftpFile=%temp%\TempAcc.txt
>"%ftpFile%" echo %ftpUser%
>>"%ftpFile%" echo %ftpPass%
>>"%ftpFile%" echo cd "%ftpFolder%"
>>"%ftpFile%" echo bin
>>"%ftpFile%" echo mget DSTAT_1PASS.*.%yesterday%*.txt
>>"%ftpFile%" echo bye
start ftp -v -i -s:"%ftpFile%" %ftpIP%

rem 根据实际情况自行调节延迟时间
ping -n 600 127.1 >nul

move /y DSTAT_1PASS.*.%yesterday%*.txt "%DownFolder%"
复制代码

lazygc520

经测试通过，可以用。谢谢l楼上两位仁兄的帮忙！
顺便再问个以外的话题，如果有N个这样的程序按顺序先后执行，是不是要清空TempAcc.txt的内容？
假如像以下的代码：

start /wait  /b cmd /c T5581-01.cmd
ping -n 10 127.1 >nul
start  /wait /b cmd /c T5581-02.cmd
ping -n 10 127.1 >nul
start /wait  /b cmd /c T5581-03.cmd
ping -n 10 127.1 >nul
start /wait  /b cmd /c T5581-04.cmd
ping -n 10 127.1 >nul
start /wait  /b cmd /c T5581-05.cmd
ping -n 10 127.1 >nul
........
复制代码

[ 本帖最后由 lazygc520 于 2009-4-10 16:20 编辑 ]

Batcher

不需要
代码会自动清空的