[分享]批处理利用set /p与重定向输入分行获取文本内容

CrLf

起因是前几天的某个帖子中看到 cmd<1.txt 的用法，原以为1.txt 中的 pause 之所以被跳过是因为执行完后马上接收到了一个回车符，于是我把1.txt 中的所有 pause 都改成 pause&rem ，并去除所有回车符进行试验，下为去除回车符的代码：

@echo off&setlocal enabledelayedexpansion
set hh=^


::获取换行符
for %%a in (
        "@echo off" "pause&rem" "echo abc" "pause&rem"
) do set str=!str!!hh!%%~a
echo !str:~2!>3.txt
::只用换行符断行

cmd<3.txt
echo;
echo ________end________
pause
复制代码

假设修改后 1.txt内容如下（测试时，此文本中不存在回车符）：

@echo off
pause&rem
echo abc
pause&rem
复制代码

结果仍然没有等待用户输入，并且还吞掉了下一行 echo 的第一个字符，导致 cmd 显示：

        请按任意键继续. . .
        'cho' 不是内部或外部命令，也不是可运行的程序
        或批处理文件。
        请按任意键继续. . .
复制代码

对此感到非常疑惑，百思不得其解之下去请教寒夜版主，他问我 pause 等待的是什么输入，我才忽然醒悟，原来 pause 等待的是“任意键”，也就是说，它把 echo 的 e 当作用户输入给接收了（因为行末的 0D 0A被 cmd 接收了，所以 pause 接收的第一个字符就是下一行的首字符 e），因此这里用 pause 无法实现暂停的效果，这就推翻了我原来的认识，证明等待用户输入的命令并不是以回车符作为终止输入的信号。
（另：其实现想来这个问题也好解决，既然是类似 cmd /c "pause"<1.txt 这样的原因造成 pause 从 1.txt 获取了任意输入，那么改成 pause<con 即可重定向为从键盘获取输入）

进一步思考一下，众所周知， set /p 首行=<1.txt 能获取 1.txt 第一行，那么对含有大量 set /p 的语块进行重定向，又是什么结果呢？

@echo off
(for /l %%a in (1 1 10) do set /p .%%a=)<%0
set.
pause
复制代码

可以看到，通过 set /p 配合重定向，能够把文本每一行都设为变量值，这是全新的技巧，更重要的是，这是一种全新的遍历文本的方式，它相当于不跳过空行的 for until ，这与 for /f 的 skip 参数相映成趣，而且还对特殊字符有极佳的兼容性。不过有得必有失，使用 set /p 赋值时，变量长度不能超过 1024 字节，所以局限了这个技巧的适用范围。
        
激动之余，又产生了两个疑惑：
    1、set /p 是以什么为依据断行
    2、当循环数大于文本行数时，为什么没有停顿下来等待用户输入

和寒夜版主一起做了几个试验，证明无论是单纯的 0D 回车符或者 0A 换行符都无法实现平时在 cmd 窗口中敲回车结束 set /p 输入的效果，必须出现连续的一组 0D 0A 才能够终止对一个 set /p 的输入。关于终止 set /p 输入的“特征码”，25 楼的 mxxcgzxxx 提出了更合理的猜想：0D 0A 和 0A 0D 这两种组合都能起到终止 set /p 输入的作用。
(25楼链接：http://bbs.bathome.net/viewthrea ... muid=30406#pid86638)
        
而第二个问题，绕了半天弯子终于得到一个比较合理的猜测：当重定向的输入被前面执行的命令取用完的时候，剩下的就是从空设备的输入，也就是 set /p .5=<nul。所以假如文本有N行，那么超过第 N 次的 set /p 都接收到了来自空设备的输入因而没有被赋值，示例如下，假设原 bat 为：

(set /p .a=
set /p .b=)<只有一行的文件.txt
set.
复制代码

其作用相当于：

set /p .a=<只有一行的文件.txt
::取首行
set /p .b=<nul
::从空设备获取输入，等于无输入
set.
::显示以 . 开头的变量
复制代码

通过这个猜测和其他一些命令接收重定向输入时表现出的特性衍生出一个推测，那就是 cmd 在接受重定向输入到命令的时候，也许是一个字符一个字符顺序传递给语块\语句的，那些能够接受重定向输入的命令会自发地从中获取输入，直到命令自行关闭输入句柄为止。
        
这可以理解为 cmd 中出现重定向输入的时候，输入中的字符在排队等候被命令依次提走，一直到无字符可提的时候，重定向输入的来源就成为了一个空设备 nul。
        
好比一个旅行团在打车，出现愿意载客的出租车时，队伍就有序地依次上车，一辆车客满后就再等下一辆（旅行团并不知道当前这辆车何时客满，他们只需要机械地让排头的人上车、直到司机喊停为止），最终所有人都打车走光，这时候新来的出租车就找不到客人了，所以空车离开时当然还是空车。
        
当然有些命令是以任意合法字符或者固定字符来判定何时结束输入的，比如 choice、set /p 和 pause，这就很有利用的价值。
        
此处仅以 set /p 举几个例子：

@echo off
set /p line=要获取的行所在行数：
(for /l %%a in (1 1 %line%) do set /p 内容=)<a.txt
set 内容
::获取指定行内容的新方法，由于无需遍历整个文本，要获取的行位置靠前的情况下有很大优势
复制代码

@echo off
(for /l %%a in (1 1 100) do set /p .%%a=)<%0

::不跳过空行赋值，但是 tmplinshi 版主的测试结果表明这比常规办法稍慢，它只在某些场合有优势，比如只获取前 N 行时，或者要兼容空行的情况，再或者需要兼容特殊字符的时候。
复制代码

(5楼链接：http://bbs.bathome.net/viewthrea ... muid=30406#pid86516)

@echo off&setlocal enabledelayedexpansion

set n=1
(for /l %%a in (1 1 5) do (
    if defined .!n! set /a n+=1
    set /p .!n!=
))<%0
::当然也同样可以跳过空行只将前 N 行赋值，但是这里的“前 N 行”计数时其实还是包括空行的，如果是要求取不把空行计算在内的前 N 行，我想最经济的方法就是先用 findstr . a.txt 输出非空行再分别赋值了
复制代码

@echo off
(for /l %%a in (1 1 7) do (
    pause
    set /p echo=
    echo !echo!
)<%0
::去除每行行首第一个任意字符的另一种方法，如果不计较效率的话，用 choice 可以只保留指定字符
复制代码

@echo off
(for /l %%a in (1 2 7) do (
    set /a a=1,b=2
    set /p a=
    set /p b=
    if !a!==!b! echo 相等
)<%0
::以两行为周期判断其内容是否相等，这比起老方法省下了许多麻烦，比如无需用 setlocal、endlocal 来兼容特殊字符
复制代码

@echo off
(for %%a in (
1-关回显 2-循环体 3-循环内容 4-do 4-设变量 5-输入 6-查看变量 7-注释
) do (
    set /p .%%a=
))<%0
set.
::可以通过无参数的for来循环，实现了以往无法实现的效果
复制代码

@echo off&setlocal enabledelayedexpansion
(for /f "tokens=1* delims=:" %%a in ('findstr /n .* 1.txt') do (
    set t2=
    set /p t2=
    echo;%%b!t2!
))<2.txt>合并.txt
::由于可以有两个不同的输入来源并存，所以双文本乃至多文本合并就成为轻而易举的事了
复制代码

@echo off&setlocal enabledelayedexpansion
for %%a in (a\*.txt b\*.txt) do set /a n+=1
dir /b /a-d /o-n b\*.txt>list.$
::计算文件总数为 %n%，生成要复制的文件列表为 list.$
(for /l %%a in (1 1 %n%) do (
	if not exist a\%%a.txt (
		set /p f=
		copy "b\!f!" "a\%%a.txt"
	)
))<list.$
::以往让人头疼的按递增文件名复制文件的问题，也可以这样解决
del /f list.$>nul
pause
复制代码

无奈的是，可以分段接受重定向输入的命令寥寥无几，所以暂时还没有想到更多的实用技巧，还是等待大家来补充吧。

感谢 寒夜孤星、mxxcgzxxx、tmplinshi 等人的指点和共同探讨、测试。

mxxcgzxxx

由于楼主的研究精神，于是乎截取文本头几行，或截取文本指定行的问题迎刃而解！
赞一个

tmplinshi

不错，有一定的实用性。

例如，再也不用使用 findstr 来保留空行了，只不过要知道文本的行数。示例：

@echo off
set str=
(
    for /l %%a in (1 1 7) do (
        setlocal enabledelayedexpansion
        set /p str=
        if defined str (echo !str!) else echo ---------空行
        endlocal
    )
) <a.txt
pause
复制代码

CrLf

获取文件行数可以用：

find /c /v ""<1.txt
复制代码

虽然也是外部命令，但是效率比 findstr /n 要高

tmplinshi

我测试了一个 11651 行的文本（没有空行），结果是 for /f 更快。

测试代码：

set_p.bat：

@echo off
(
    for /l %%a in (1 1 11651) do (
        setlocal enabledelayedexpansion
        set /p str=
        echo,!str: =_!
        endlocal
    )
) <test.txt >test_1.txt
复制代码

for_f.bat：

@echo off
(
    for /f "delims=" %%a in (test.txt) do (
        set str=%%a
        setlocal enabledelayedexpansion
        echo,!str: =_!
        endlocal
    )
) >test_2.txt
复制代码

测试结果：

e:\我的文档\桌面>timeit set_p.bat

Version Number:   Windows NT 5.1 (Build 2600)
Exit Time:        10:19 am, Monday, July 18 2011
Elapsed Time:     0:00:15.500
Process Time:     0:00:14.031
System Calls:     430474
Context Switches: 56632
Page Faults:      39304
Bytes Read:       19381026
Bytes Written:    741100
Bytes Other:      2573192

e:\我的文档\桌面>timeit for_f.bat

Version Number:   Windows NT 5.1 (Build 2600)
Exit Time:        10:20 am, Monday, July 18 2011
Elapsed Time:     0:00:12.484
Process Time:     0:00:12.328
System Calls:     159911
Context Switches: 2458
Page Faults:      15433
Bytes Read:       598486
Bytes Written:    597572
Bytes Other:      2345164

tmplinshi

@echo off
setlocal enabledelayedexpansion
(
    for /l %%a in (1 1 7) do (
        pause >nul
        set /p echo=
        echo !echo!
    )
) <%0
pause
复制代码

有点想不通的是，pause 为什么不直接接收 %0 的内容，而要接收它下一行的 set /p。

cjiabing

很好很强大，值得研究

mxxcgzxxx

@echo off
setlocal enabledelayedexpansion
(
    for /l %%a in (1 1 10) do (
        pause >nul
        set /p echo=
        echo !echo!
    )
)
tmplinshi 发表于 2011-7-18 10:36

有趣的结果：起头的（）被忽略，最后一个P被上一行吃了
所以用这种办法还得小心

tmplinshi

8# mxxcgzxxx


是每一行前面的第一个字符没有了，顶楼有说。

mxxcgzxxx

9# tmplinshi
哦，是啊，没注意，pause吃了后面的输入！
也就是说<%0被分成了两下，第一个字被pause吃了，剩下的才轮到set/p,
可以用作去头几个字符用了

@echo off
setlocal enabledelayedexpansion
::从每行第三个字符截取
(
    for /l %%a in (1 1 10) do (
        for /l %%1 in (1 1 3) do pause >nul
        set /p echo=
        echo %%a !echo!
        )
) <%0
pause
复制代码

CrLf

6# tmplinshi

5楼结果是因为 for 会跳过空行，如果要兼容空行的话，结果就要反过来了...
pause 是有接收字符的，它接收“任意字符”，也就是把每行开头的那个字符给吞了

mxxcgzxxx

下面这个测试很有趣。空行被吃一个字符后，理应是换行符被吃，但造成换行符加下一行的（被吸上来了

@echo off
setlocal enabledelayedexpansion

(
    for /l %%a in (1 1 10) do (
        pause>nul
        set /p echo%%a=
        echo %%a !echo%%a!
        )
) <%0
pause
复制代码

tmplinshi

12# mxxcgzxxx


截图工具推荐用 FSCapture：
    颜色少的用 png 格式，保存时选 256 色；
    颜色多的用 jpg 格式，比如人物照片等。

Batcher

13# tmplinshi


Reduce Color, 2 Colors
这样是不是更小更清晰

mxxcgzxxx

13# tmplinshi

学习，之前没想过这个问题哈，是要省点空间
我都是用抓屏键，用图画工具弄的，换成PNG反面有50多KB