CrLf

5# tmplinshi


我用2235行的厚黑学全集试了试（题外话，下载回来都木油看过，原来这玩意就是用来测试的...），结果相差无几
for /f：

@echo off
echo %time%
(
    for /f "delims=" %%a in (test.txt) do (
        set str=%%a
        setlocal enabledelayedexpansion
        echo,!str: =_!
        endlocal
    )
) >test_2.txt
echo %time%
pause
复制代码

回显：

 0:55:30.77
 0:55:32.83
请按任意键继续. . .
复制代码

set /p：

@echo off
echo %time%
(
    for /l %%a in (1 1 2235) do (
        setlocal enabledelayedexpansion
        set /p str=
        echo,!str: =_!
        endlocal
    )
) <test.txt >test_1.txt
echo %time%
pause
复制代码

回显：

 0:55:34.07
 0:55:36.37
请按任意键继续. . .
复制代码

结果是 2.04:2.30，差距约为十分之一...视实际情况而定吧，毕竟遍历方式以及来源的异同决定了这两种用法有各自适用范围~

batman

很好，很强大！！！
庆贺又一bathome原创技术的诞生！！！

mxxcgzxxx

从特殊字符方面来说还是有很大区别的

!@#~#$%^&*()_+-={}|":?><;'\`"~!@#$%^&*()_+|":?><
复制代码

用SET/P和FOR/F分别读取并输出

@echo off
setlocal enabledelayedexpansion
(
    for /l %%a in (1 1 1) do (
        set/p echo=
        echo.!echo!
        )
) <1.txt >2.txt

for /f "delims=" %%1 in (1.txt) do (
       set "str=%%1"
       echo !str!
       )>>2.txt
复制代码

结果

!@#~#$%^&*()_+-={}|":?><;'\`"~!@#$%^&*()_+|":?><
?><;'\`"~?><
复制代码

说明，如果在有特殊字符的情况下，SET/P更加合理而简便

mxxcgzxxx

@echo off
setlocal enabledelayedexpansion
(
       set/p a=
       set/p b=
       set/p c=
       echo.!a!
       echo.!b!
       echo.!c!
       )<1.txt >2.txt
复制代码

这样子是一次性获取头三行信息，
利用这个可进行隔行获取

@echo off
(
     for /l %%1 in (1 1 10 ) do (
       setlocal enabledelayedexpansion
       set/p 偶数行=
       set/p 奇数行=
       echo.!偶数行!>>2.txt
       echo.!奇数行!>>3.txt
       endlocal
       )
)<1.txt 
复制代码

测试了多种组全发现，SET/P可以全文吸收一个字符都不错，
但无法跳过空行是一个优点也是一大问题

CrLf

18# mxxcgzxxx

可以用开闭变量延迟来提升对特殊字符的兼容性，但是我没测试过这个动作对效率的影响：

@echo off
for /f "delims=" %%1 in (1.txt) do (
       endlocal
       rem 此时关闭变量延迟以免 %%1 中含有 ! 致错
       set "str=%%1"
       setlocal enabledelayedexpansion
       rem 此时打开变量延迟以即时读取变量
       echo !str!
)>>2.txt
复制代码

另外，要跳过的行可以不赋值...三行一周期，获取周期中的首尾两行：

(@echo off

for /l %%a in (1 1 12) do (
    set .1=
    set .2=
    set /p .1=
    set /p=
    set /p .3=
    echo;!.1!
    echo;!.2!
))<%0
pause
复制代码

确实，不跳过空行既是优点也是缺点，另外还有两个不知道是优点还是缺陷的特性，一是 set /p 接收到空输入时不会清空该变量原有值，二是无法一步到位地完成变量赋值、加前后缀、切割等等复杂动作。

CrLf

12# mxxcgzxxx


刚刚又去向无所不能的寒夜版主请教，我们原来以为 pause 会把紧随其后的 0D 0A 整个吞掉（因为曾经尝试用 pause 取换行符无果），但是12楼的代码举了个反例，这实在让我想不通，难道 pause 能提前判断下一行是否非空、当下一行不为空时则只吞 0D 吗？

后来找到了一个更为合理的假设，那就是 pause 本来就只吞碰到的第一个字符，此处的第一个字符也就是回车符 0D，而 set /p 继续接收第二行输入时接到了 0A ( 0D 0A，所以出现了换行效果。但是当第二行也是空行时，set /p 接收到的就是 0A 0D 0A，我们猜测 set /p 默认不会将单纯的换行符 0A 设为变量，所以 set /p 赋值为空。

做了个实验证明这一点：

@echo off


(for /l %%a in (1 1 10) do (
pause>nul
pause>nul
rem 用两个pause测试，看究竟是否吞了两组 0D 0A，如果 pause 是吞整个 0D 0A，那结果应该不会出现空行或者带换行符的变量
set /p .%%a=))<%0
set.
pause
复制代码

结果果然空了一行，证明每个 pause 确实只是取走紧随其后其后的那个字符，而非能够“预知”下一行的内容。

mxxcgzxxx

21# zm900612
听起来是这个理，但下面这个情况怎么解释呢？

@echo off



(for /l %%a in (1 1 10) do (
pause>nul
rem 用两个pause测试，看究竟是否吞了两组 0D 0A，如果 pause 是吞整个 0D 0A，那结果应该不会出现空行或者带换行符的变量
set /p .%%a=))<%0
set.>1.txt
pause
复制代码

输出的1.txt为

.1=echo off
.4=for /l %%a in (1 1 10) do (
.5=ause>nul
.6=em 用两个pause测试，看究竟是否吞了两组 0D 0A，如果 pause 是吞整个 0D 0A，那结果应该不会出现空行或者带换行符的变量
.7=et /p .%%a=))<%0
.8=et.>1.txt
.9=ause

按理应该是下面这样取值的啊，为什么到3行出错了？然道说第三行的 0D 0A 可以用两次

@echo off 0D 0A
0D 0A
0D 0A
0D 0A
(for /l %%a in (1 1 10) do ( 0D 0A
pause>nul0D 0A
rem 用两个pause测试，看究竟是否吞了两组 0D 0A，如果 pause 是吞整个 0D 0A，那结果应该不会出现空行或者带换行符的变量0D 0A
set /p .%%a=))<%0 0D 0A
set.>1.txt 0D 0A
pause 0D 0A

.1=echo off
.2=0A 0D 0A
.3=0A
for /l %%a in (1 1 10) do (
.4=ause>nul
...

mxxcgzxxx

有半个换行符的值写入文本后会出现一个像退格符的黑块，但我发不上论坛，
可以对TXT文本进行复制并写到批处理里面，很好用也
但无法通过变量截取的方式获得有点可惜！

CrLf

22# mxxcgzxxx


诡异，测试后发现一次循环中只有一个 pause 时，连续空行数以一种奇怪的规律影响着变量的赋值：当连续空行数量为1、4、6、8...等数字时，会出现行首带有换行符的变量，这究竟是什么原因导致的呢...我也想不通了

mxxcgzxxx

24# zm900612


那可以这样理解吗？ 0D 0A 和0A 0D 都可以起到结束SET/P的输入过程
三行空行时
0D 0A
0D 0A
0D 0A
第一个0D被吃  SET/P得到0A 0D （强行终结）
第二个0A被吃   SET/P得到0D 0A （完整）
这样还能解释为什么三个空行被赋值两次
0A 0D 的组合有没有代表什么？
5个空行情况：
吃 ---- 留
0D---0A| 0D
0A|---0D  0A|
0D---0A| 0D
0A|---文本，所以正常不换行

以此类推，基本都合理了
1空行：0A 换行文本
2空行：完整文本
3空行：文本少头一字符
4空行：0A 换行文本
5空行：完整文本
。。。三个空行一个循环，所以：
1，4，7，10。。。为换行文本
2，5，8，11。。。为不少字的完整文本
0，3，6，9。。。为少头一字符的文本

刚才测试了下，完全符合这个规律！

CrLf

25# mxxcgzxxx


好！确实很有可能，测试代码如下：

@echo off
set x0a=^



::空行请自行添加
for /f %%a in ('copy /z %~s0 nul') do set x0d=%%a
cmd /v:on /c echo abc!x0a!!x0d!123!x0a!!x0d!>1.txt
(for /l %%a in (1 1 10) do set /p .%%a=)<1.txt
set.
pause>nul
复制代码

证明确实是以三行为一周期（汗一个，早先对此的测试结果是忘了加上被换行的那一行的，所以当时测试所得的周期很没有规律...误导人啊误导人），而且很有可能确实是像老兄说的那样，只要碰到一组 0D 0A，无论它们字符顺序如何，都能结束 set /p 的输入行为。

可用如下代码进行验证：

@echo off&setlocal enabledelayedexpansion
set a=^


(for /f %%a in ('copy /z %0 nul') do set b=%%a
set<nul /p=赋值成功!a!!b!赋值失败)>1.txt
set /p e=<1.txt
echo !e!
pause
echo d|debug 1.txt
::如果未出现赋值失败的字眼则代表 0A 0D 成功地结束了 set /p 的输入，结果证明确实如此
复制代码

越来越完善了

mxxcgzxxx

用提取的换行符玩下，虽然不知实用性在哪方面可以应用？
因为论坛会吃单空格行，所以我使用：号

 
:
@echo off
::获取0A换行符
(pause>nul&set /p a=)<%0
echo 你好%a%我在哪?
pause>nul
复制代码

由于半个换行让“我在哪？”进行了无间道，不存在的东西
但开了变量延时后就不一样了

 
:
@echo off
setlocal enabledelayedexpansion
::获取0A换行符
(set/p=&pause>nul&set /p a=)<%0
echo 你好！!a!我在哪啊？!a!你也不知道吗？!a!真是可惜……
pause>nul
set "b=123!a!456!a!789"
echo !b!
pause>nul
复制代码

效果不是太理想但也很好了，一次三行内容，就是后面的每行多一个符号，可以加个退格符就可以了！！
而且可以通过赋值传达给别的函数，但一定要开变量延时和加上一个退格符！

我也搜索了论坛，应该来说这个方法是快而简便获取换行符的方法，
又一个新技术诞生了哈！

 
:
@echo off
setlocal enabledelayedexpansion
::获取0A换行符
(pause>nul&set /p a=)<%0
::通过赋值用退格符将换行符后的空格修整得到完整实用的换行符
set "b=!a!"
echo !b!123456!b!789
pause>nul
复制代码

raymai97

回复 27# mxxcgzxxx


    其实我有些混乱了，你的代码的意思是这样么？

(pause>nul&set /p a=)<%0
复制代码

利用批处理开头来获取换行字符和空格字符

set "b=!a!"
复制代码

换行+空格+退回字符=换行+不会再退回的退回字符=完整实用的换行符？

就达成了0d 0a组合的目的？

netbenton

这个真的是新发现，竟然还支持嵌套，看来多个文件合并也可以了

@echo off
(set/p a1=

   (set /p b1=
   set /p b2=
   )<bb.txt

set/p a2=)<aa.txt


set a
set b

pause
复制代码

DAIC

回复 30# netbenton


版主请帮忙看看这个合并文件时处理特殊字符的问题吧
http://bbs.bathome.net/thread-13735-1-1.html